Формирование огибающей сигнала

ВЫРАБОТКА СИГНАЛА-ПЕРЕНОСЧИКА ИНФОРМАЦИИ

Огибающую можно сформировать с помощью ЦАП, последовательно загружая в него коды, пропорциональные амплитуде функции синус или квадрат синуса. Перемножение огибающей и несущей частот осуществляется с помощью мультиплексора (рис. 5.1).

Рис. 5.1

Количество точек огибающей на интервале времени Т ₀ выбирается исходя из заданной точности формирования и обычно лежит в диапазоне от 20 до 100.

Задавшись количеством точек огибающей D, можно рассчитать период вывода кодов в ЦАП: Т_D = Т ₀/ D. Здесь Т ₀ – рассчитанная по выражению из разд. 1 длительность передаваемого бита.

Для формирования временных интервалов Т_D можно воспользоваться одним из таймеров, имеющихся в составе однокристальной ЭВМ. Таймер 0 в режиме автозагрузки инкрементирует регистр TL0 с частотой F _osc / 12. При переполнении TL0 устанавливается флаг TF0 и перезагружается содержимое регистра TH0 в TL0. Процесс счета продолжается с нового значения TL0 (рис. 5.2). Следовательно, таймер 0 осуществляет деление частоты кварцевого генератора процессора F _osc до требуемого значения.

Коэффициент деления частоты таймером 0 K ₀ может принимать значение от 40 до 256. Минимальное значение K ₀ ограничено временем выполнения команд вывода очередной точки огибающей в ЦАП. Если предположить, что в памяти программ ОЭВМ с адреса TABSIN расположен массив огибающей, состоящий из D точек, и таймер 0 генерирует период формирования точек огибающей Т_D, то вывод каждой точки огибающей в ЦАП нужно синхронизировать с флагом переполнения таймера TF0.

Рис. 5.2
;Программа инициализации таймера 0
INIT0:	MOV MOV MOV SETB	TMOD,#2 TH0,#256-J TL0,TH0 TR0	;режим автозагрузки таймера 0 ;K0 – коэффициент деления частоты;Fosc/12 таймером 0 ;пуск таймера 0

Подпрограмма вывода бита информации из флага переноса CARRY в порт P1.1 с формированием огибающей с помощью ЦАП, подключенного к P2, имеет вид:

OUTB:	MOV	DPTR,#TABSIN	;адрес первой точки огибающей
	MOV	R0,#D	;счетчик точек
;ожидание завершения очередного периода T0
OUTBW:	JNB	TF0,OUTBW	;ожидание TF0
	CLR	TF0	;сброс TF0
	MOV	P1.1,C	;информационный бит
	CLR	A	;ввод в ACC очередной
	MOVC	A,@A+DPTR	;точки огибающей
	MOV	P2,A	;вывод ее в ЦАП
	INC	DPTR	;адрес следующей точки
	DJNZ	R0,OUTBW	;цикл вывода
	RET

Основным недостатком данной программы является то, что процессор постоянно находится в режиме ожидания для вывода каждой точки огибающей, хотя, в принципе, его основная задача – заниматься выводом информационного бита. Производительность ОЭВМ падает примерно в число точек огибающей раз. В результате программа может не успеть сформировать очередной информационный бит между последней точкой огибающей текущего информационного бита и первой последующего, поскольку только в этот момент времени осуществляется выход из подпрограммы вывода бита. Это возможно при использовании АЦП с большим временем преобразования или с большим временем доступа, более сложного закона формирования синхропоследовательности или при выполнении каких-либо других задач. Поэтому целесообразно разбить данный сложный процесс на два: формирование огибающей и вывод бита.

Формирование огибающей необходимо возложить на подпрограмму обработки прерывания таймера 0. Если разрешить прерывания от таймера 0, то при его переполнении происходит аппаратное обращение к подпрограмме, расположенной по адресу 0BH. Эта подпрограмма производит вывод очередной точки и возврат в основную программу.

При выводе последней точки огибающей подпрограмма обработки прерывания производит инициализацию адреса массива огибающей на следующий период, восстановление счетчика точек D и установку признака завершения вывода очередного периода огибающей. Этим признаком может быть какой-либо флаг (бит) или байт, который может распознавать основная программа. Основная программа занимается только подготовкой (опрос АЦП, ввод цифровой информации и пр.) и формированием выходного информационного бита. При обнаружении установленного признака завершения очередного периода огибающей основная программа сбрасывает его и выводит очередной информационный бит (рис. 5.3).

Рис. 5.3

Пример подпрограммы инициализации таймера 0 для вывода огибающей в прерывании.

INIT0:	MOV MOV MOV	TMOD,#2 TH0,#256-J TL0,TH0	;режим автозагрузки ;K0 – коэффициент деления частоты;таймером 0
	MOV	DPTR,#TABSIN	;адрес первой точки огибающей
	MOV	R7,#D	;счетчик точек
	MOV	IE,#82H	;разрешение прерывания от таймера 0
	SETB	TR0	;пуск таймера 0
	RET

Подпрограмма обработки прерывания таймера 0 для вывода огибающей в порт P2 (признаком завершения вывода периода огибающей служит флаг 20H.0):

	ORG	0BH
IRQT0:	PUSH	ACC	;сохранение аккумулятора перед его;использованием
	CLR	A	;ввод в ACC очередной
	MOVC	A,@A+DPTR	;точки огибающей
	MOV	P2,A	;вывод ее в ЦАП
	INC	DPTR	;адрес следующей точки
	DJNZ	R7,IRQTE	;цикл вывода
;вывод периода огибающей завершен
	MOV	DPTR,#TABSIN	;адрес первой точки огибающей
	MOV	R7,#D	;счетчик точек
	SETB	20H.0	;период огибающей завершен
IRQTE:	POP	ACC	;возврат аккумулятора
	RETI		;выход из п/п прерывания

В основной программе:

;п/п вывода бита данных из флага carry в порт P1.1
OUTB:	JNB	20H.0,OUTB	;ожидание 20H.0
	CLR	20H.0	;сброс 20H.0
	MOV	P1.1,C	;информационный бит
	RET

В приведенном примере основная программа не связана с выводом каждой точки огибающей, а лишь с периодом следования выходных бит данных. Производительность процессора возрастает примерно в D раз. В основной программе запрещено применение регистров DPTR и R7, поскольку они используются подпрограммой обработки прерывания.

Дата добавления: 2014-12-27