Названия цветов 7 страница

Примеры применения оператора if-else

Рассмотрим несколько примеров, демонстрирующих использование оператора if-else.

Задача 9. Составить программу, в которой реализуются следующие условия: если цена по финансовому инструменту поднялась выше некоторого значения, сообщить об этом трейдеру, а если нет, то не осуществлять никаких действий.

Один из вариантов решения этой задачи может выглядеть, например, так (onelevel.mq4):

//--------------------------------------------------------------------

// onelevel.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------------

int start() // Спец. функция start

{

double

Level, // Сигнальный уровень

Price; // Текущая цена

Level=1.2753; // Задаём уровень

Price=Bid; // Запрашиваем цену

//--------------------------------------------------------------------

if (Price>Level) // Оператор if с условием

{

Alert("Курс превысил заданный уровень");// Сообщение трейдеру

}

//--------------------------------------------------------------------

return; // Выход из start()

}

//--------------------------------------------------------------------

Прежде всего необходимо отметить, что программа создана как эксперт. Этим полагается, что программа будет находиться в работе достаточно долго, с тем чтобы, когда текущая цена превысит заданный уровень, на экране появилось интересующее нас сообщение. В программе имеется всего одна специальная функция start(). В начале функции объявлены и прокомментированы переменные. Далее численно задаётся уровень цены и запрашивается текущая цена.

Oператор if-else используется в следующих строках программы:

//----------------------------------------------------------------------------------

if (Price>Level) // Оператор if с условием

{

Alert("Курс превысил заданный уровень");// Сообщение трейдеру

}

//----------------------------------------------------------------------------------

С момента, когда в выполняющейся программе управление передано в оператор if-else, начинается проверка его условия. Обратите внимание, проверка условия в операторе if-else является его собственным свойством. Эта проверка во время исполнения оператора if-else не может быть проигнорирована, она являет суть и смысл самого оператора и будет выполнена обязательно. В дальнейшем, в зависимости от результата этой проверки, управление будет передано либо в тело оператора, либо за его пределы - в оператор, следующий за закрывающей фигурной скобкой.

На рис. 37 представлена функциональная схема, в соответствии с которой могут развиваться события при исполнении оператора if-else.

Рис. 37. Функциональная схема исполнения оператора if-else в программе onelevel.mq4.

В этой и последующих схемах ромб символизирует проверку условия. Стрелки показывают куда будет передано управление после исполнения текущего блока операторов (термин "блок операторов" означает некоторый произвольный набор операторов, находящихся в непосредственной близости друг к другу). Рассмотрим схему более подробно.

К блоку Предыдущие вычисления (серый прямоугольник на схеме) в программе onelevel.mq4 относятся следующие:

double

Level, // Сигнальный уровень

Price; // Текущая цена

Level=1.2753; // Задаём уровень

Price=Bid; // Запрашиваем цену

После исполнения последнего оператора в этом блоке управление передаётся на заголовок оператора if-else, в котором проверяется условие Цена выше заданной? (ромб на схеме, рис. 37):

if (Price>Level) //Оператор if с условием

Иными словами, можно сказать, что на этом этапе программа ищет ответ на вопрос, является ли заключённое в круглые скобки утверждение истинным. Само утверждение звучит буквально так, как оно написано: значение переменной Price больше значения переменной Level (цена больше заданного уровня). К моменту, когда программа определяет истинность этого утверждения, у неё уже имеются численные значения переменных Price и Level. И ответ зависит от соотношения этих значений. Если курс ниже заданного уровня (значение Price меньше или равно значению Level), то утверждение ложно, а если выше, то утверждение истинно.

Таким образом, куда будет передано управление после проверки условия, зависит от текущей ситуации на рынке (!). Если цена по финансовому инструменту остаётся ниже заданного уровня (ответ - Нет, т.е. утверждение ложно), то, в соответствии с правилом исполнения оператора if-else, управление будет передано за пределы оператора, в данном случае - в блок Последующие вычисления, а именно в строку:

return; // Выход из start()

При этом легко увидеть, что сообщение трейдеру не выдаётся.

Если же цена по финансовому инструменту превышает заданный в программе уровень (ответ - Да, т.е. утверждение истинно), то управление передаётся в тело оператора if-else, а именно в строки:

{
Alert("Курс превысил заданный уровень");// Сообщение трейдеру
}

Результатом исполнения функции Alert() будет появление на экране небольшого окна с надписью:

Курс превысил заданный уровень

Функция Alert() является единственным оператором тела оператора if-else, поэтому после её исполнения оператор if-else является полностью выполненным, а значит управление должно быть передано оператору, следующему за ним, т.е. в строку:

return; // Выход из start()

В результате исполнения оператора return функция start() закончит свою работу и программа перейдёт в режим ожидания тика. На новом тике (несущем и новую цену по финансовому инструменту) функция start() будет снова исполнена. И в зависимости от того, превысил или не превысил текущий курс заданный уровень, будет или не будет выдано заложенное в программу сообщение.

Операторы if-else могут быть вложенными. Для того чтобы продемонстрировать использование вложенных операторов, обратимся к следующему примеру. Здесь задача уже несколько усложнена.

Задача 10. Составить программу, в которой реализуются следующие условия: если цена поднялась выше некоторого значения 1, то сообщить об этом трейдеру, если цена опустилась ниже некоторого значения 2, то сообщить об этом трейдеру, в остальных случаях не осуществлять никаких действий.

Понятно, что для решения этой задачи в программе необходимо дважды проверять текущую цену:

- находится ли цена выше-ниже уровня 1;

- находится ли цена выше-ниже уровня 2.

Решение задачи 10. Вариант 1

Действуя формально, можно составить следующий алгоритм решения:

Рис. 38. Функциональная схема исполнения операторов if-else в программе twolevel.mq4.

Программа, реализующая этот алгоритм, может выглядеть так (twolevel.mq4):

//--------------------------------------------------------------------

// twolevel.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------------

int start() // Спец. функция start

{

double

Level_1, // Сигнальный уровень 1

Level_2, // Сигнальный уровень 2

Price; // Текущая цена

Level_1=1.2850; // Задаём уровень 1

Level_2=1.2800; // Задаём уровень 2

Price=Bid; // Запрашиваем цену

//--------------------------------------------------------------------

if (Price > Level_1) // Проверка верхн уровня

{

Alert("Цена находится выше уровня 1");// Сообщение трейдеру

}

//--------------------------------------------------------------------

if (Price < Level_2) // Проверка нижнего уровня

{

Alert("Цена находится ниже уровня 2");// Сообщение трейдеру

}

//--------------------------------------------------------------------

return; // Выход из start()

}

//--------------------------------------------------------------------

Нетрудно заметить, что код в программе twolevel.mq4 является расширенным вариантом программы onelevel.mq4. Если раньше у нас был только один уровень, относительно которого проводились вычисления, то теперь таких уровней стало два. Каждый из уровней задан численно, и для решения поставленной задачи в программе имеются два блока, отслеживающие поведение цены - находится ли она в коридоре значений, ограниченном заданными уровнями, или за его пределами.

Кратко охарактеризуем исполнение программы.

После выполнения предварительных вычислений управление поступает в первый оператор проверки if-else:

//----------------------------------------------------------------------------------

if (Price > Level_1) // Проверка верхн уровня

{

Alert("Цена находится выше уровня 1");// Сообщение трейдеру

}

//----------------------------------------------------------------------------------

Независимо от того, какие события произойдут при исполнении этого оператора (будет ли выдано сообщение трейдеру), по окончании его исполнения управление будет передано в следующий оператор if-else:

//----------------------------------------------------------------------------------

if (Price < Level_2) // Проверка нижнего уровня

{

Alert("Цена находится ниже уровня 2");// Сообщение трейдеру

}

//----------------------------------------------------------------------------------

В результате последовательного исполнения обоих операторов становится возможным осуществить обе проверки и в конечном счёте - решить поставленную задачу. Несмотря на то, что программа полностью выполняет задачу, представленный вариант решения нельзя считать абсолютно корректным. Обратите внимание на одну немаловажную деталь: второй проверочный блок выполняется независимо от результатов, полученных при проверке в первом блоке. Выполнение второго программного блока осуществляется даже в том случае, если цена превысила первый уровень.

Здесь необходимо заметить, что одной из важных целей, преследуемых программистом при составлении программ, является оптимизация алгоритма. Рассматриваемые примеры - лишь демонстрация, поэтому являют собой короткую, а значит и быстро исполняемую программу. Программа, которую предполагается использовать в практической работе, обычно значительно больше. Она может обрабатывать значения сотен переменных, использовать множество проверок, каждая из которых выполняется в течение некоторого времени. В результате этого появляется опасность, что длительность работы специальной функции start() превысит временной промежуток между тиками. Это будет означать, что некоторые тики могут остаться необработанными. Разумеется, это - крайне нежелательная ситуация, и программисту следует прилагать усилия для того, чтобы не допустить этого. Одним из методов уменьшения времени исполнения программы является оптимизация алгоритма.

Посмотрим на последний пример ещё раз, теперь уже с точки зрения экономии ресурсов. Например, какой смысл проводить во втором блоке проверку "Цена ниже заданной?", если при проверке в первом блоке уже выяснилось, что цена выше верхнего уровня? Понятно, что в этом случае цена не может оказаться ниже нижнего уровня, значит, при этих условиях выполнять проверку во втором блоке (а также исполнять набор операторов в этом блоке) нет необходимости.

Решение задачи 10. Вариант 2

Учитывая эти рассуждения, рассмотрим следующий, оптимизированный алгоритм:

Рис. 39. Функциональная схема исполнения операторов if-else в программе twoleveloptim.mq4.

В соответствии с алгоритмом, представленным на этой схеме, лишние операции выполняться уже не будут. После подготовительных вычислений проводится проверка Цена выше заданной? В случае, если цена выше, то выдаётся сообщение трейдеру и управление передаётся на Последующие вычисления, при этом анализ ситуации по второму критерию (Цена ниже заданной?) не производится. И только в том случае, если цена не оказалась выше верхнего уровня (ответ - Нет), управление передаётся на второй проверочный блок, в котором и проводится необходимая при этих условиях проверка. Если цена оказывается ниже нижнего уровня, то выдаётся соответствующее сообщение, а если нет, то управление передаётся на дальнейшие вычисления. Очевидно, что при работе программы по этому алгоритму никаких лишний действий не производится, в результате чего вычислительные ресурсы расходуются лишь по мере необходимости.

Программная реализация этого алгоритма предполагает использование вложенного оператора if-else (twoleveloptim.mq4):

//--------------------------------------------------------------------

// twoleveloptim.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------------

int start() // Спец. функция start()

{

double

Level_1, // Сигнальный уровень 1

Level_2, // Сигнальный уровень 2

Price; // Текущая цена

Level_1=1.2850; // Задаём уровень 1

Level_2=1.2800; // Задаём уровень 2

Price=Bid; // Запрашиваем цену

//--------------------------------------------------------------------

if (Price > Level_1) // Проверка верхн. уровня

{

Alert("Цена находится выше уровня 1"); // Сообщение трейдеру

}

else

{

if (Price < Level_2) // Проверка нижнего уровня

{

Alert("Цена находится ниже уровня 2");// Сообщение трейдеру

}

}

//--------------------------------------------------------------------

return; // Выход из start()

}

//--------------------------------------------------------------------

Обратите внимание на этот блок вычислений:

//--------------------------------------------------------------------

if (Price > Level_1) // Проверка верхн. уровня

{

Alert("Цена находится выше уровня 1"); // Сообщение трейдеру

}

else

{

if (Price < Level_2) // Проверка нижнего уровня

{

Alert("Цена находится ниже уровня 2");// Сообщение трейдеру

}

}

//--------------------------------------------------------------------

Оператор if-else, в котором проверяется второе условие, является составной частью первого оператора if-else, проверяющего первое условие. Применение вложенных операторов очень распространено в практике программирования, зачастую является оправданным, а в некоторых случаях - единственным возможным решением. Разумеется, в реальных программах вместо функции Alert() могут быть использованы другие функции или операторы, выполняющие полезные действия.

В качестве условия в операторе if-else может быть использовано сложное выражение.

Задача 11. Составить программу, в которой реализуются следующие условия: если цена находится в заданном диапазоне значений, то не осуществлять никаких действий; если цена вышла за пределы заданного диапазона, то сообщить об этом трейдеру.

Условие этой задачи похоже на условие Задачи 10. Разница состоит в том, что в данном случае нас не интересует, в какую именно сторону ушла цена - выше или ниже заданного диапазона. По условию задачи нам достаточно знать только сам факт - находится цена внутри коридора или за его пределами. При этом может использоваться один и тот же текст сообщения.

Здесь, как и в предыдущих решениях, необходимо проверять положение цены относительно двух уровней - верхнего и нижнего. Алгоритм решения, представленный на рис. 38, нами уже был отвергнут ранее как неэффективный. Поэтому в соответствии с последними рассуждениями можно предложить такой вариант решения:

Рис. 40. Функциональная схема одного из вариантов алгоритма решения Задачи 11.

Однако в использовании такого алгоритма нет необходимости. На схеме наглядно показано, что данный алгоритм предполагает использование в разных местах программы одного и того же блока сообщений. Программные строки будут повторяться, несмотря на то что результатом их исполнения будут одинаковые сообщения. Гораздо эффективнее в данном случае использовать один оператор if-else со сложным условием:

Рис. 41. Функциональная схема исполнения оператора if-else в программе compoundcondition.mq4.

Код программы, реализующий этот алгоритм, выглядит так (compoundcondition.mq4):

//--------------------------------------------------------------------

// compoundcondition.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------------

int start() // Спец. функция start

{

double

Level_1, // Сигнальный уровень 1

Level_2, // Сигнальный уровень 2

Price; // Текущая цена

Level_1=1.2850; // Задаём уровень 1

Level_2=1.2800; // Задаём уровень 2

Price=Bid; // Запрашиваем цену

//--------------------------------------------------------------------

if (Price>Level_1 || Price<Level_2) // Проверка сложн услов

{

Alert("Цена находится за пределами диапазона");// Сообщение

}

//--------------------------------------------------------------------

return; // Выход из start()

}

//--------------------------------------------------------------------

Ключевым моментом в этом программном решении является использование сложного условия в операторе if-else:

if (Price>Level_1 || Price<Level_2) // Проверка сложн услов

{

Alert("Цена находится за пределами диапазона");// Сообщение

}

Написанное простыми словами, это условие выглядит так: если значение переменной Price больше значения переменной Level_1 или значение переменной Price меньше значения переменной Level_2, то исполнять тело оператора if-else. Использование логических операций (&&, || и!) при составлении условий операторов if-else разрешено и широко применяется в практике программирования (см. Логические операции).

При решении других задач может возникнуть необходимость составления ещё более сложных условий, что вполне допустимо. При этом часть выражений может быть заключено в круглые скобки, в том числе вложенные. Например, в качестве условия в операторе if-else возможно использование такого выражения:

if (A>B && (B<=C || (N!=K && F>B+3))) // Пример сложного условия

Таким образом, язык программирования MQL4 предоставляет широкие возможности для использования операторов if-else: они могут быть вложенными, сами могут заключать вложенные структуры, использовать простые и сложные проверочные условия, в результате чего становится возможным составление простых и сложных программ с разветвлённым алгоритмом.

Оператор цикла while

Наиболее мощным средством языка MQL4 является возможность организации циклов.

Довольно часто при создании прикладных программ приходится использовать повторяющиеся вычисления, чаще это бывают одни и те же программные строки. Для того чтобы программирование было удобным, а сама программа - понятной, используются операторы циклов. В составе MQL4 имеется два оператора цикла - while и for. Здесь мы рассмотрим первый из них.

Формат оператора while

Полноформатный оператор цикла while состоит из заголовка, содержащего условие, и исполняемого тела цикла, обрамлённого фигурными скобками.

while ( Условие ) // Заголовок оператора цикла
{ // Открывающая фигурная скобка
Блок операторов, // Тело цикла может состоять..
составляющих тело цикла //.. из нескольких операторов
} // Закрывающая фигурная скобка

Если в операторе while тело цикла составляет один оператор, то фигурные скобки можно опустить.

while ( Условие ) // Заголовок оператора цикла
Один оператор, тело цикла // Тело цикла - один оператор

Правило исполнения оператора while

Пока Условие оператора while является истинным: передать управление первому оператору тела цикла, а после выполнения всех операторов тела цикла передать управление в заголовок для проверки истинности Условия. Если условие оператора while является ложным, передать управление оператору, следующему за оператором while.

Рассмотрим пример.

Задача 12. Вычислить коэффициент Фибоначчи с точностью до 10-го знака.

Кратко охарактеризуем коэффициент Фибоначчи. Итальянский математик Леонардо Фибоначчи обнаружил уникальную последовательность чисел:

1 1 2 3 5 8 13 21 34 55 89 144 233...

Каждое число в этой последовательности является суммой двух предыдущих чисел. Представленная последовательность чисел обладает уникальными свойствами: отношение любого числа к предыдущему равно 1.618, а к следующему - 0,618. Коэффициент 1.618 получил название коэффициента Фибоначчи, а указанная последовательность называется последовательностью Фибоначчи (отметим также, что 0,3819 - сопряжённая величина для коэффициента Фибоначчи, получена в результате его умножения на самого себя: 0.3819 = 0.618 х 0.618).

Задача состоит в том, чтобы вычислить коэффициент Фибоначчи более точно. Если проанализировать коэффициент Фибоначчи для нескольких десятков элементов последовательности, то становится очевидным, что полученные коэффициенты колеблются вокруг иррационального числа 1.61803398875..., принимая поочерёдно то большие, то меньшие значения. Чем большие числа из последовательности участвуют в вычислениях, тем меньше отклонение от указанного значения.

Заранее неизвестно, какие именно числа необходимо взять, чтобы их коэффициенты отличались между собой не более, чем в десятом знаке. Поэтому необходимо составить программу, которая будет последовательно перебирать коэффициенты до тех пор, пока разница между ними не окажется меньше 0.0000000001.

В данном случае для решения Задачи 12 создан скрипт (fibonacci.mq4), потому программа не будет использоваться в длительной работе на каждом тике. После присоединения к окну финансового инструмента скрипт должен один раз выполнить необходимые вычисления (в том числе показать результат), после этого он будет выгружен из окна клиентским терминалом.

//--------------------------------------------------------------------

// fibonacci.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------------

int start() // Спец. ф-ия start()

{

//--------------------------------------------------------------------

int i; // Формальн параметр,счётчик

double

A,B,C, // Числа последовательности

Delta, // Фактич. разница между Кф

D; // Заданная точность

//--------------------------------------------------------------------

A=1; // Начальное значение

B=1; // Начальное значение

C=2; // Начальное значение

D=0.0000000001; // Задаём точность

Delta=1000.0; // Начальное значение

//--------------------------------------------------------------------

while(Delta > D) // Заголовок оператора цикла

{ // Скобка начала тела цикла

i++; // Счётчик

A=B; // Следующее значение

B=C; // Следующее значение

C=A + B; // Следующее значение

Delta=MathAbs(C/B - B/A); // Искомая разница между Кф

} // Скобка конца тела цикла

//--------------------------------------------------------------------

Alert("C=",C," Число Фибоначчи=",C/B," i=",i);//Сообщение на экран

return; // Выход из start()

}

//--------------------------------------------------------------------

В начале программы производится объявление переменных (и даётся их описание). В последующих строках переменным присваиваются численные значения. А, В и С получают значения первых чисел последовательности Фибоначчи. Здесь необходимо отметить, что, хотя в самой последовательности идёт речь о целых числах, частное от их деления должно быть учтено в программе как действительное число. Если бы в данном случае был использован тип int для этих чисел, то не было бы возможности вычислить коэффициент Фибоначчи, например, 8/5 = 1 (целое число 1, то есть без дробной части). Поэтому в данном случае использован тип переменных double. Собственно оператор цикла выглядит так:

while(Delta > D) // Заголовок оператора цикла

{ // Скобка начала тела цикла

i++; // Счётчик

A=B; // Следующее значение

B=C; // Следующее значение

C=A + B; // Следующее значение

Delta=MathAbs(C/B - B/A); // Искомая разница между Кф

} // Скобка конца тела цикла

Рассмотрим функциональную схему оператора цикла while:

Рис. 42. Функциональная схема исполнения оператора while в программе fibonacci.mq4.

Оператор цикла начинает свою работу с проверки условия. Многократное выполнение цикла будет повторяться до тех пор, пока условие (Delta>D) является истинным. Понимание кода программы существенно упрощается, если при чтении операторов произносить ключевую фразу - правило исполнения. Например, при чтении оператора while это фраза: " До тех пор пока.., выполнять следующее:.. ". В данном случае заголовок оператора while звучит так: до тех пор, пока Delta больше D, выполнять следующее.. И далее можно перейти к анализу программных строк, составляющих тело цикла и исполняемых в случае истинности этого Условия.

Перед тем как управление в приведенном примере fibonacci.mq4 передано оператору цикла while, значения этих переменных соответственно равны 1000.0 и 0.0000000001, поэтому при первом обращении к оператору цикла условие является истинным. Это значит, что после проверки условия управление будет передано первому оператору, составляющему тело оператора цикла.

В данном примере - это оператор:

i++; // Счётчик

В трёх последующих строках вычисляются значения очередного набора элементов последовательности:

A = B; // Следующее значение
B = C; // Следующее значение
C = A + B; // Следующее значение

Легко увидеть, что переменные принимают значения следующих (ближайших больших) элементов. Если до исполнения оператора цикла значения А, В и С были равны соответственно 1.0, 1.0 и 2.0, то в процессе первой итерации эти переменные принимают значения 1.0, 2.0 и 3.0.

Итерация -повторное выполнение некоторых вычислений; используется для обозначения факта исполнения программных строк, составляющих тело оператора цикла.

В следующей строке вычисляется интересующая нас разница между коэффициентами Фибоначчи, полученным на основе последующих (C/B) и предыдущих (B/A) элементов последовательности:

Delta = MathAbs(C/B - B/A); // Искомая разница между Кф

В этом операторе используется стандартная функция MathAbs(), вычисляющая абсолютное значение выражения. Ранее указывалось, что по мере увеличения значений элементов последовательности, коэффициенты Фибоначчи принимают поочерёдно то большие, то меньшие значения, в сравнении с "эталоном". Поэтому разница между соседними коэффициентами будет принимать то отрицательное, то положительное значение. В то же время, нас интересует собственно величина этого отклонения, т.е. её абсолютное значение. Таким образом, независимо от того, в какую сторону отклонилось текущее значение коэффициента Фибоначчи, значением выражения MathAbs(C/B - B/A), а также значением переменной Delta, всегда будет положительное число.

Этот оператор является последним в списке операторов, составляющих тело цикла, о чём свидетельствует наличие в следующей строке закрывающей фигурной скобки. После исполнения последнего оператора тела цикла управление передаётся в заголовок оператора цикла для проверки условия. В этом состоит ключевой момент, определяющий сущность оператора цикла. В зависимости от того, является ли теперь истинным условие оператора цикла, управление будет передано либо на очередную итерацию в тело цикла, либо за пределы оператора цикла.

Дата добавления: 2014-12-29