Комп’ютерна модель. Обчислювальний експеримент

Зважаючи на специфіку цієї задачі, вхідні дані, окремі таблиці та діаграми пропонуємо розташувати дещо інакше, ніж до цього. Зокрема, вигляд перших шести рядків буде таким:

	A	B	C	D	E	F
	ІМІТАЦІЙНЕ МОДЕЛЮВАННЯ: ЗАДАЧА УПРАВЛІННЯ
	Втрати від 1 год. простою обладнання -
	Вартість 1 транзистора -
	Кількість випробуваних транзисторів, N -
	Крок нарощування часу, год., h -

1. На початку роботи перейдіть у режим ручного управління
обрахунками. Зокрема, в MS Excel це робиться так: «Сервис» →
«Параметры» → «Вычисления». Далі користуйтеся клавішею F9.

У перших п’яти рядках розмістимо заголовок і вхідні дані.

Шостий рядок залишимо порожнім, він буде відокремлювати умову від наступних робочих таблиць.

Наступні рядки 7–19 містять Таблицю 1.

	A	B	C	D	E	F
	Таблиця 1. Розподіл строків роботи транзисторів
		Години роботи	Відмов	Разом	Відносна
		від	до			частота відмов
	0					0,000
	1					0,008
	2					0,090
	3					0,274
	4					0,620
	5					0,922
	6					0,992
	7					1,000
	і		xі		nі	yі

Внесемо уточнення.

1.1. Комірки 11-го рядка разом з групою D11–D18 заповнюються з клавіатури згідно Таблиці 1. Винятком є С11 і F11:

комірки	формули
С11	=$F$5
F11	=E11/$F$4

1.2. Вміст комірок 12-го рядка має бути таким:

комірки	формули	примітки
А12	=A11+1	копіювати в А13–А18
В12	=C11+1	копіювати в В13–В18
С12	=C11+$F$5	копіювати в С13–С18
Е12	=D12+E11	копіювати в E13–E18
F12	=E12/$F$4	копіювати в F13–F18

2. За даними комірок С11–С18 (аргументи або в термінології таблиць – категорії) і F11–F18 (значення) побудуємо криву розподілу відносних частот (ймовірностей) виходу з ладу транзи­сторів у відповідності з рис. 12.2. Розташуємо цю діаграму праворуч від умови і Таблиці 1 орієнтовно в області комірок Н2–М20.

3. Нижче, у рядках 21–32 створимо дві допоміжні таблиці
(Таблицю 2 і Таблицю 3). В Таблиці 2 помістимо значення кутових коефіцієнтів k_і, що будуть обчислюватись згідно виразу

k_і = (y_{і+ 1}- y_і) / h = n_і / (h·N),

а в Таблиці 3 розташуємо рівномірно розподілені псевдовипадкові числа y_і з інтервалу [0, 1], генеровані спеціальною функцією.

	A	B	C	D	E	F	G	H	І
	Таблиця 2. Визначення
	кутових коефіцієнтів kі
	kі = (yі+1- yі) / h = nі / (h·N)		Таблиця 3. Випадкові числа yі
		і	kі			1-й	2-й	3-й	4-й
			0,00000			0,530	0,603	0,038	0,407
			0,00004			0,260	0,937	0,310	0,911
			0,00041			0,195	0,810	0,140	0,807
			0,00092			0,312	0,891	0,704	0,140
			0,00173			0,564	0,395	0,049	0,177
			0,00151			0,294	0,823	0,598	0,849
			0,00035			0,779	0,378	0,994	0,034
			0,00004			0,139	0,907	0,302	0,972

Всі комірки Таблиці 3 заповнюються однаково:

комірка	формула	примітки
F25	=СЛЧИС()	копіювати в F25–І32

3. Будемо моделювати час, через який відбуватимуться відмови обладнання протягом року. Відповідну до цього Таблицю 4 помістимо в рядки 34–45 (комірки з області А34–І45):

	A	B	C	D	E	F	G	H	І
	Таблиця 4. Моделювання тривалості роботи обладнання
	№	1-й транзист.	2-й транзист.	3-й транзист.	4-й транзист.
	заміни	Години	Всього	Години	Всього	Години	Всього	Години	Всього
		роботи	годин	роботи	годин	роботи	годин	роботи	годин

3.1. Стовпець А заповнюється зовсім просто:

комірки	формули / числа
А38
А39	=А38+1 (копіювати у всі решта комірок стовпця А)

3.2. Складніше зі стовпцем В (D, F, H). Саме в його комірках реалізується автоматичне обчислення строків безперервної роботи першого (другого, третього, четвертого) транзистора, тобто інтервалів часу між його послідовними замінами. Тут перевіряється, якому із семи інтервалів належить випадкове число у ₁ (комірка F25), й у
відповідності до цього обчислюється час безперервної роботи транзистора за формулою (2):

комірка	формула
В38	=$F$5+ ЕСЛИ(И(F25>=$F$11;F25<$F$12);(F25-$F$12)/$C$26+$C$11)+ ЕСЛИ(И(F25>=$F$12;F25<$F$13);(F25-$F$13)/$C$27+$C$12)+ ЕСЛИ(И(F25>=$F$13;F25<$F$14);(F25-$F$14)/$C$28+$C$13)+ ЕСЛИ(И(F25>=$F$14;F25<$F$15);(F25-$F$15)/$C$29+$C$14)+ ЕСЛИ(И(F25>=$F$15;F25<$F$16);(F25-$F$16)/$C$30+$C$15)+ ЕСЛИ(И(F25>=$F$16;F25<$F$17);(F25-$F$17)/$C$31+$C$16)+ ЕСЛИ(И(F25>=$F$17;F25<$F$18);(F25-$F$18)/$C$32+$C$17)

Примітка. Для прискорення набору цієї формули можна, набравши вираз першої функції ЯКЩО («ЕСЛИ») і знак додавання, скопіювати їх шість разів і виконати необхідне редагування всього виразу. Аналогічно можна діяти при заповненні решти комірок цього стовпця. Після заповнення стовпця В всі його формули (комірки) слід
помітити й одночасно скопіювати у стовпці D, F і H. Далі слід виконати необхідне редагування.

3.3. У стовпцях С, Е, G, І для кожного з чотирьох транзисторів, по-перше, здійснюється нагромадження загального часу роботи з урахуванням усіх виконаних замін і, по-друге, при переході цього часу через 4200 год. значення його обнуляється. Комірки С38, Е38, G38, І38 містять посилання на своїх сусідок зліва (замін іще не було):

комірки	формули
	С38	=В38
	Е38	=D38
	G38	=F38
	І38	=H38

Формули в С39, Е39, G39, І39 мають вигляд:

комірки	формули
С39	=ЕСЛИ(ИЛИ(И(C38<5800;C38>4200);C38=0);0;C38+B39)
Е39	=ЕСЛИ(ИЛИ(И(E38<5800;E38>4200);E38=0);0;E38+D39)
G39	=ЕСЛИ(ИЛИ(И(G38<5800;G38>4200);G38=0);0;G38+F39)
І39	=ЕСЛИ(ИЛИ(И(І38<5800;І38>4200);І38=0);0;І38+H39)

Кожну з цих формул слід копіювати в решту комірок свого стовпця.

Примітка. При аналізі вмісту комірки С39 може скластися
думка, що логічна операція АБО, до складу якої входить перевірка умови C38 = 0, зайва (в С38 завжди буде число, більше за 200). Це ж саме стосується і комірок E39, G39 та І39. Але як би тоді в декількох останніх комірках згаданих стовпців могли б з’явитись нулі? Тим більше, що кількість нульових комірок заздалегідь невідома.

Вправа

1. Прокоментуйте рядок:

=ЕСЛИ(ИЛИ(И(C38<5800;C38>4200);C38=0);0;C38+B39)

2. З яких міркувань, на вашу думку, з’явилось верхнє обмеження 5800 (тобто 4200 + 1600)?

3. З Таблиці 4 видно, що 2-й транзистор набере більше, ніж 4200 годин роботи після третьої заміни, 1-й і 4-й транзистори – після четвертої заміни, а 3-й прийдеться міняти п’ять разів. Тільки після всіх цих замін загальний час роботи кожного транзистора перебільшить 4200 годин, тобто чергові відмови обладнання відбудуться вже в наступному році.

4. Для більшої наочності дані про кількість замін кожного
транзистора подамо у підсумковій Таблиці 5.

	A	B	C	D	E	F
	Таблиця 5. Кількість замін кожного транзистора
		№	Кількість
		транзист.	замін
		разом:
		Втрати від простоїв -
		Вартість транзисторів -
				разом:

Розглянемо вміст комірок цієї таблиці.

4.1. Комірки С50–С53 та С54:

комірки	формули
С50	=СЧЁТЕСЛИ(C38:C45;">0") –1
	=СЧЁТЕСЛИ(Е38:Е45;">0") –1
С52	=СЧЁТЕСЛИ(G38:G45;">0") –1
С53	=СЧЁТЕСЛИ(I38:I45;">0") –1
С54	=СУММ(C50:C53)

Після копіювання слід відредагувати формули в С51, С52, С53.

Таким чином, протягом року може відбутися 16 відмов, і стільки ж транзисторів доведеться замінити. То ж підрахуємо втрати:

4.2. Комірки Е59–Е61:

комірки	формули
Е59	=C54*F2
Е60	=C54*F3
Е61	=СУММ(E59:E60)

від простоїв 100·16 = 1600 у.о.;

вартість транзисторів 5·16 = 80 у.о.;

разом – 1680 у.о.

4.3. Дані про моменти відмов кожного транзистора зобразимо на діаграмі «Календарний графік ремонтів».

Примітка. Для успішної побудови цієї діаграми слід виконати наступні дії:

а) виділити комірки B38:B45, D38:D45, F38:F45, H38:H45;

б) вибрати тип діаграми «Линейчатая»;

в) обравши опцію «Исходные данные», на вкладці «Диапазон
данных» встановити:

а на вкладці «Ряд» взяти 8 рядів: від Ряд 1 по Ряд 8;

г) на отриманій діаграмі обрати опцію «Формат оси» і у відповідному вікні на вкладці «Шкала» встановити

мінімальне значення 0

максимальне значення 4200

ціна основних поділок 500

ціна проміжних поділок 100

Нижче подано результат:

5. Тепер з’ясуємо, чи можна так організувати обслуговування, аби зменшити час простою обладнання, тобто кількість ремонтів. Пропозиція про підвищення надійності транзисторів виключається одразу, оскільки підприємство одержує їх готовими.

5.1. Проаналізуємо, що буде, коли за кожної відмови деякого
одного транзистора, механік буде міняти не лише дефектний, а одразу всі чотири, тобто весь блок. Результат такої операції заздалегідь передбачити складно, оскільки тепер заміна відбуватиметься після відмови транзистора із самим коротким строком служби.

Якщо вважати, що за нової системи обслуговування будуть
використовуватися ті самі транзистори, або точніше, з тими самими строками служби, то з метою одержання необхідної інформації можна скористатися даними з Таблиці 4. Однак тепер з неї треба брати дані про строк безвідмовної роботи після 1-го, 2-го і наступних ремонтів. Той транзистор, у якого цей строк після чергового ремонту буде найменшим, і визначатиме момент наступної відмови (заміни) і, отже, наступного ремонту. Одержані результати зведені в Таблиці 6:

	A	B	C	D	E	F
		Таблиця 6. Кількість ремонтів за новою
		організацією обслуговування –
		№	№	Строк	Усього
		ремонту	транзистора	роботи	годин
					758
					1244
					2003
					2673
					3455
					4298
					0
					0

5.2. Комірки Таблиці 6 мають такий уміст:

комірка	формула
С67	=ЕСЛИ(МИН(B38;D38;F38;H38)=B38;1; ЕСЛИ(МИН(B38;D38;F38;H38)=D38;2; ЕСЛИ(МИН(B38;D38;F38;H38)=F38;3;4)))

Примітка. Вміст С67 копіювати в решту комірок стовпця.

комірки	формули	примітки
D67	=МИН(B38;D38;F38;H38)	копіювати в С68–С74
Е67	=МИН(C38;E38;G38;І38)
Е68	=ЕСЛИ(ИЛИ(И(E67<5800;E67>4200);E67=0);0;E67+D68)	копіювати в Е69–Е74
F64	=7-(ЕСЛИ(E74=0;1;0)+ ЕСЛИ(E73=0;1;0)+ ЕСЛИ(E72=0;1;0)+ ЕСЛИ(E71=0;1;0))

6.2. Підсумкові результати формуємо у такий спосіб:

	G	H	І	J	K
		Втрати від простоїв -
		Вартість транзисторів -
				разом:
	Ефективність нової організації
	обслуговування -	2,80

Уміст комірок такий:

комірка	формула
К66	=F64*F2
К67	=4*F64*F3
К68	=СУММ(K66:K67)
К71	=E61/K68

7.2. З Таблиці 6 видно, що за рік тепер відбудеться п’ять ремонтів. За тих самих умов обчислення втрат це складе:

внаслідок простою: 100·5 = 500 у.о.;

вартість транзисторів: 5·(4·5) = 100 у.о.;

разом – 600 у.о.

Отже, за нової організації системи обслуговування загальні втрати складатимуть 600 у.о. проти 1680 у.о., тобто без будь-яких додаткових коштів, а виключно завдяки іншій організації обслуговування втрати можна зменшити більше, ніж у 2 рази.

Вправа

1. Прокоментуйте формули в комірках С50–С53, С67, D67, Е67, Е68, F64

2.. Переведіть електронну таблицю з автоматичного на ручний режим перерахунків.

3. Повторюючи багаторазово пп. 4–7 перерахуванням таблиць 2–6 (з новими значеннями випадкових чисел – F9), отримуємо середнє значення показника ефективності обслуговування, яке має підтвердити отриманий вище результат.

4. За якої умови ефективність нової організації обслуговування залишиться попередньою, тобто не зміниться?

5. Виконайте від самого початку дослідження за умови, що час моделювання, який становив 4200 годин протягом року, стане
величиною змінною. Це дозволить міняти графік роботи підприємства (кількість змін, кількість робочих годин протягом зміни тощо).

Висновки

1. В ході розв’язування задачі було проведене дослідження двох операцій, пов’язаних з організацією технічного обслуговування
виробничого обладнання. У першій операції була реалізована схема: «відмова одного елемента → його заміна», у другій операції схема була змінена: «відмова елемента → заміна всього блоку». Якщо в якості критерію ефективності технічного обслуговування прийняти відношення виробничих втрат внаслідок відмов за попередньою і новою схемами, то, зрозуміло, особа, котра приймає рішення,
надасть перевагу організації ремонтів за другою схемою. Якби критерій ефективності був інший, наприклад, вартість транзисторів, то перевага була б віддана першій схемі.

2. Таким чином, імітаційне моделювання в управлінській діяльності часто дозволяє відрізнити потенційно продуктивні рішення, що ведуть до успіху, від помилкових.

Слід, однак, пам’ятати, що будь-яка модель завжди є спрощеним образом об’єкту, а результатам моделювання можна довіряти лише після того, як вони будуть підтверджені хоча б одним із доступних способів: натурними спостереженнями (або ще краще – натурним експериментом), іншими моделями того самого об’єкту, висновками відповідної теорії, бажано перевіреної попередньою практикою і т.п.

3. Привабливість та ефективність методу Монте-Карло полягає в тому, що з допомогою рівномірно розподілених випадкових (псевдовипадкових) чисел за відомим законом розподілу можна моделювати реальні випадкові події. Вся історія цього методу, численні приклади його ефективного застосування на практиці переконують, що цей порівняно простий метод є дуже популярним у практиці імітаційного комп’ютерного моделювання.

Цікаво відмітити, що випадкові числа, які з філософської точки зору найчистіше являють собою відображення нашого незнання, кладуться в основу методів, за допомогою яких дослідники пізнають поведінку складних систем.

4. При моделюванні випадкових величин їх реальний розподіл визначають або за певним теоретичним законом методами математичної статистики, або на основі дослідних даних, які отримують
шляхом здійснення спеціального натурного експерименту.

5. Основу управління і взагалі всіх «розумних» дій комп’ютера становлять логічні операції. Як ми переконалися, створення таких команд потребує особливої уваги і досвіду.

Дата добавления: 2015-01-03