Создаем ловца

Порядок создания объектов

Этап проектирования

Хватит теории. Садимся за компьютер. Создайте новый проект. Для краткости дайте форме имя f. Разместите на форме элемент управления Shape - это будут бортики нашего стола. Размер стола не имеет значения, потому что мы так запрограммируем шары и ловца, что они будут чувствовать бортики. Разместите на форме кнопку cmd_Начинай_сначала и текстовое поле txtСчетчик_времени

Украсьте как-нибудь проект. Только не надо ничем заливать прямоугольник стола и не надо помещать на форму фотографию - шары будут тормозить.

Создайте модуль кода. В нем нам будет удобно объявлять глобальные элементы нашего проекта.

Создание объектов пользователя в Visual Basic проходит в два этапа:

1. Создается собственный пользовательский класс объектов. Аналогия: пусть ваш объект - алюминиевая тарелка. Тогда класс объектов Тарелка есть штамп, которым мы можем наштамповать сколько угодно объектов-тарелок. Вся работа по созданию механизма будущего объекта проходит именно на этом этапе.

2. По готовому классу объектов создается ("штампуется") сам объект или, как его еще называют, экземпляр класса. Для этого достаточно двух строчек кода. Экземпляров с разными именами можно создать сколько угодно. Можно создать и массив объектов (именно это мы впоследствии и сделаем, создав массив из 10 объектов-шаров).

Итак, согласно вышесказанному мы создадим два класса объектов с именами clsЛовец и clsШар. Затем по классу clsЛовец создадим объект Ловец, а по классу clsШар создадим массив объектов Шар(1 To 10).

Разобьем создание проекта тоже на две ступени. На первой ступени мы создадим ловца, а шаров не будет. Проект будет функционировать нормально, только без шаров. На второй ступени проект будет готов полностью.

Приступим к созданию класса clsЛовец. Каждый пользовательский класс объектов создается в собственном модуле класса. Ведь форма - это модуль, модуль кода - модуль, и класс тоже требует своего модуля, который и будет той "упаковкой", в которой безопасно будут работать его данные и процедуры.

Значит, создаем модуль класса. Делается это просто: Project ® Add Class Module® New ®Class Module® Open. И вот перед вами чистое окно кода модуля класса. Впечатление совсем такое же, как при создании модуля кода. В этом окне вы будете объявлять переменные объекта и писать процедуры и функции, из которых и состоит вся механика объекта. Никаких элементов управления и формы у модуля класса нет.

В окне свойств модуля класса дайте имя своему классу - clsЛовец. Сохранимся. Мы видим, что Visual Basic сохраняет модуль класса в отдельный файл. Придадим файлу имя Ловец.cls. Все готово. Можно бы писать код. Но это делать еще рано. Сначала нужно очень точно продумать поведение нашего ловца, все, что он должен уметь делать. Выпишем все его умения:

А. По приходе импульса от таймера он должен:

· Сдвинуться на некоторый шаг вверх, вниз, влево, вправо, подчиняясь соответствующим клавишам клавиатуры, или стоять (клавиша Ctrl).

· Проверить, не наткнулся ли он на бортик, и если да, то остановиться.

В. При нажатии кнопки "Начинай сначала" возвращаться в исходное положение и там останавливаться.

Все. Вы спросите, а как же умение ловить шары, ради которого ловец и создан? Я отвечу - В нашем случае проще запрограммировать "исчезалки", чем "ловилки". Поясню. Наткнувшись на шар, ловец не будет предпринимать никаких действий по его "поимке". Наоборот, шар, наткнувшись на ловца, потрудится исчезнуть. Со стороны - никакой разницы.

Запрограммируем все действия, перечисленные в пункте А, в одной процедуре, и назовем ее Действие. Запрограммируем все действия, перечисленные в пункте В, в другой процедуре, и назовем ее Начальная_установка.

Объект пользователя - мозг без тела

Я уже говорил о разнице между модулями формы и кода. Модуль формы снабжен элементами, которые мы собственными глазами видим на экране: это сама прямоугольная форма и элементы управления, расположенные на ней. У модуля кода ничего визуального нет, это просто набор переменных, констант, типов, процедур и функций. Модуль класса в этом повторяет модуль кода. Он может своими процедурами обеспечивать сколь угодно сложное поведение и движение объекта, но все это где-то там, глубоко в памяти компьютера, а самого объекта и движения вы никогда на экране не увидите, так как в модуле класса, как и в модуле кода нет встроенных средств визуализации. Что же делать? Приходится модулю класса пользоваться чужими средствами, конкретно - элементами управления формы.

Поместите на форму два элемента управления Image, одному дайте имя imgЛовец, другому - imgШар (в дальнейшем из imgШар мы породим массив элементов управления imgШар(1 To 10)). Они-то и будут теми актерами, которым предназначено изображать живую жизнь наших бестелесных объектов. Это просто марионетки. Умные объекты будут дергать их за ниточки, и они будут надлежащим образом двигаться по экрану. Всем окружающим будет казаться, что это движутся сами объекты. Придайте им соответствующие картинки.

У модуля класса нет ни одного элемента управления, значит и таймера тоже нет. Таймером нашего проекта будет таймер, принадлежащий форме. Поместите его на форму. Задайте ему интервал = 10. Щелкните по нему дважды - в окне кода формы появится заготовка процедуры. Напомню, что эта процедура выполняется на каждом импульсе таймера. Значит это и будет главная процедура нашего проекта, задающая ритм всем объектам и элементам управления.

Перечислю действия, которые должна выполнять эта процедура:

· Разбудить по очереди Шар(1), Шар(2), … Шар(10) и заставить каждого выполнить свою невидимую работу, в частности вычислить свое положение (координаты) на форме.

· Переместить элементы управления imgШар(1), imgШар(2), … imgШар(10) в положение, вычисленное их объектами Шар(1), Шар(2), … Шар(10).

· Разбудить ловца и заставить его выполнить свою процедуру Действие, в частности вычислить свое положение (координаты) на форме.

· Переместить элемент управления imgЛовец в положение, вычисленное объектом Ловец.

· Увеличить на 1 счетчик времени (импульсов таймера) на форме.

Перечислю действия, которые должны выполняться при нажатии на кнопку "Начинай сначала":

· Установить в 0 счетчик времени

· Установить в 0 переменную-счетчик пойманных шаров. Он нам понадобится, чтобы определить момент окончания игры - как только счетчик станет равен 10.

· Заставить ловца выполнить свою процедуру Начальная_установка, то есть прыгнуть в точку старта ловца и там остаться.

· Заставить каждый из шаров прыгнуть в точку старта шаров и подготовиться к старту.

Как создать объект по его классу

Сначала объект Ловец нужно объявить как экземпляр класса clsЛовец. Точно так же, как мы объявляем переменную величину a, как хранительницу экземпляра значения типа Integer. То есть, мы объявляем, из какого "штампа" будет штамповаться наша тарелка:

Public Ловец As clsЛовец

Почему Public? Потому что наш ловец должен быть виден и из модуля формы (хотя бы для того, чтобы знать его координаты), и из модуля шара (который тоже должен знать его координаты, чтобы вовремя исчезнуть при столкновении).

Строку объявления удобнее написать в модуле кода, чтобы не надо было указывать хозяина объекта.

А теперь объект Ловец нужно создать ("отштамповать" тарелку):

Set Ловец = New clsЛовец

Слово New означает, что создается новый представитель класса объектов clsЛовец. Начиная с этого момента объектом можно пользоваться. Объекты можно создавать в любой момент работы проекта, поэтому указанную строку можно помещать в любое место кода. Поскольку наш ловец понадобится нам с самого начала, поместим эту строку в процедуру Form_Load нашей формы.

Первая ступень проекта

Итак, вот как выглядит наш проект на первой ступени. На второй ступени к модулю кода и окну кода формы просто добавятся без малейшего изменения строки, касающиеся шаров. А модуль clsЛовец я привожу, естественно, целиком, в окончательном варианте.

Модуль кода

Public Const Размер_ловца = 500

Public Ловец As clsЛовец 'Объявляем объект Ловец класса clsЛовец

Модуль формы

Private Sub Form_Load() 'Эта процедура выполняется один раз при запуске проекта

imgЛовец.Height = Размер_ловца

imgЛовец.Width = Размер_ловца

Set Ловец = New clsЛовец 'Порождаем объект Ловец

Начальная_установка

KeyPreview = True 'Чтобы форма реагировала на клавиатуру

txtСчетчик_времени.Locked = True 'Чтобы в процессе игры нельзя было вручную менять показания счетчика

End Sub

Private Sub cmd_Начинай_сначала_Click() 'Что происходит при нажатии кнопки НАЧИНАЙ СНАЧАЛА

Начальная_установка

txtСчетчик_времени.SetFocus 'Чтобы фокус ушел с кнопки, иначе первое нажатие на стрелки клавиатуры не вызывает движения ловца

End Sub

Private Sub Начальная_установка()

txtСчетчик_времени.Text = 0 'Обнуляем счетчик времени

Ловец.Начальная_установка 'Ловец встает в исходную позицию и настраивается на новую игру

End Sub

Private Sub Timer1_Timer() 'Главная_процедура игры, выполняется один раз на каждом импульсе иаймера

Ловец.Действие 'Сначала объект Ловец вычисляет свои координаты,

imgЛовец.Left = Ловец.x 'Затем изображение Ловца сдвигается на вычисленные координаты

imgЛовец.Top = Ловец.y

txtСчетчик_времени.Text = txtСчетчик_времени.Text + 1 'Действует счетчик времени на форме, увеличивая свои показания на 1

End Sub

'Обработка события - нажатия клавиши на клавиатуре для управления ловцом:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

Select Case KeyCode

Case vbKeyUp: Ловец.Руль = вверх

Case vbKeyLeft: Ловец.Руль = влево

Case vbKeyDown: Ловец.Руль = вниз

Case vbKeyRight: Ловец.Руль = вправо

Case vbKeyControl: Ловец.Руль = стоп

End Select

End Sub

Модуль clsЛовец

Public x As Long 'Координаты ловца

Public y As Long

Private dx As Long 'Шаг ловца по горизонтали и вертикали между двумя импульсами таймера

Private dy As Long

Public Enum типРуль 'Направление движения ловца или состояние неподвижности

вверх

влево

вниз

вправо

стоп

End Enum

Public Руль As типРуль

Private Sub Class_Initialize() 'Процедура, выполняющаяся при рождении ловца

dx = 100

dy = 100

End Sub

Public Sub Начальная_установка() 'Ловец встает в исходную позицию и останавливается

Руль = стоп

'Ставим ловца в исходную позицию:

x = f.shpБортик.Left + f.shpБортик.Width * 1 / 4 'Он отстоит по горизонтали на четверть ширины стола от левого его края

y = f.shpБортик.Top + f.shpБортик.Height / 2 'Он по вертикали расположен посредине стола

End Sub

Public Sub Действие() 'Главная процедура ловца, выполняется один раз на каждом импульсе таймера

Выбираем_куда_ехать_и_делаем_шаг 'Ловец слушается клавиатуру

If Ловец_у_пола_или_потолка Or Ловец_у_стен Then Руль = стоп 'Чтобы ловец случайно не улетел за пределы стола

End Sub

Private Sub Выбираем_куда_ехать_и_делаем_шаг()

Select Case Руль

Case вверх: y = y - dy

Case вниз: y = y + dy

Case влево: x = x - dx

Case вправо: x = x + dx

Case стоп: 'Поскольку никуда идти не надо, постольку ничего не делаем

End Select

End Sub

Private Function Ловец_у_пола_или_потолка() As Boolean

'ЕСЛИ ловец находится у потолка ИЛИ у пола, ТО:

If y < f.shpБортик.Top Or y + Размер_ловца > f.shpБортик.Top + f.shpБортик.Height Then

Ловец_у_пола_или_потолка = True

Else

Ловец_у_пола_или_потолка = False

End If

End Function

Private Function Ловец_у_стен() As Boolean

'ЕСЛИ ловец находится у левой стены ИЛИ у правой, ТО:

If x < f.shpБортик.Left Or x + Размер_ловца > f.shpБортик.Left + f.shpБортик.Width Then

Ловец_у_стен = True

Else

Ловец_у_стен = False

End If

End Function

Запустите проект. Проверьте, правильно ли движется ловец. У бортика он должен сам останавливаться. Его можно передвигать и за пределами стола, но с трудом.

Обратите внимание, что разные модули используют одноименные процедуры. Например, Начальная_установка. Проблемы в этом нет, так как если процедура задана, как Private, то из других модулей она просто не видна, а если даже Public, то перед своим именем она будет требовать имени хозяина.

А теперь пояснения. Работу процедур я буду разбирать в хронологическом порядке, то есть в том, в котором они вызываются после запуска проекта. Об инкапсуляции поговорим попозже.

Первой при запуске проекта выполняется процедура Form_Load. Начинается она с того, что высота и ширина элемента управления imgЛовец (см. текст программы) становятся равными константе Размер_ловца. Затем порождается объект Ловец. При этом генерируется событие - инициализация объекта - и в соответствии с этим выполняется процедура Class_Initialize в модуле класса. Там я только присваиваю значения шагу ловца. После инициализации управление возвращается в процедуру Form_Load, а там запускается процедура Начальная_установка, которая выделена в отдельную процедуру, так как выполняется не только при загрузке формы, но и при щелчке по кнопке "Начинай сначала".

Выше я уже перечислил действия, которые нужно выполнить при начальной установке. Вы видите, что в текстовом поле на форме появляется 0, затем из процедуры Начальная_установка формы запускается процедура Начальная_установка ловца. Здесь Руль устанавливается в положение стоп. Затем вычисляются координаты точки старта ловца. Возможно, у вас вызовут трудность формулы, встречающиеся в коде. Не поленитесь разобраться в них. Например, f.shpБортик.Left означает горизонтальную координату левого края элемента управления shpБортик на форме f. Как видите, объект Ловец использует для своей работы информацию о внешнем мире.

После выполния процедуры Начальная_установка ловца управление возвращается в процедуру Начальная_установка формы f. Не найдя там больше ничего, Visual Basic возвращается в Form_Load на строку KeyPreview = True. После выполнения этой и следующей строк Form_Load завершает работу и на игровой площадке наступает покой до прихода первого импульса от таймера.

Если вас затруднили все эти пассажи с возвратами управления, запустите пошаговый режим. Это прекрасный способ убедиться в правильности кода.

А теперь давайте остановимся и подумаем, что успело произойти. Если вы дошли до этого момента в пошаговом режиме, то обнаружили, что ловец, вопреки ожиданиям, не занял место на старте, несмотря на то, что координаты x и y.вычислены правильно. Это что - упущение проекта? Нет. Просто я не стал обременять процедуру Начальная_установка заботами о перемещении imgЛовец. Дело в том, что через 1/18 долю секунды все равно придет импульс от таймера и заработает процедура Timer1_Timer. Там-то и запрограммировано перемещение изображения. Никто и не заметит, что ловец встал на место не сразу.

И вот импульс грянул. Заработала процедура Timer1_Timer и первым делом запустила процедуру Ловец.Действие. Давайте пока не будем в нее заглядывать, вообразим, что там ничего существенного не произошло, и пойдем дальше. Следующие две строки как раз и перемещают изображение ловца в точку старта. Вместо 0 в счетчике на форме появляется 1. На этом процедура Timer1_Timer заканчивает свою работу. Все замирает до тех пор, пока через 1/18 долю секунды не придет следующий импульс от таймера.

Предположим, вы за это время еще не успели прикоснуться к клавиатуре. Вот импульс грянул. Заработала процедура Timer1_Timer и запустила процедуру Ловец.Действие. Рассмотрим, как она работает. Ее тело состоит из двух строк, вызывающих процедуры и функции с интуитивно ясными именами. Первой выполняется процедура Выбираем_куда_ехать_и_делаем_шаг. Руль у нас после начальной установки находится в положении стоп и ничто его оттуда не вывело, значит оператор Select Case не меняет ни x ни y.

Хорошо. Дальше выполняется следующая строка. Вызывается функция Ловец_у_пола_или_потолка. Вы можете сами убедиться, что поскольку ловец пока далеко от бортиков, то эта функция принимает значение False. Аналогично, значение False принимает и функция Ловец_у_стен. На этом вторая строка процедуры Ловец.Действие завершается, а с ней и вся процедура. Visual Basic возвращается в процедуру Timer1_Timer. Поскольку ни x ни y не менялись, то следующие две строки процедуры оставляют изображение ловца на месте.

Ждем следующего импульса. Пусть до момента его прихода мы успели нажать на клавиатуре стрелку вправо, желая направить ловца направо. Немедленно сработала процедура Form_KeyDown в модуле формы и руль встал в положение вправо. Вот пришел импульс. Опять процедура Timer1_Timer направляет нас в процедуру Ловец.Действие, та - в процедуру Выбираем_куда_ехать_и_делаем_шаг. Поскольку руль повернут направо, вычисляется новое значение x, которое на dx больше предыдущего. Возвратившись наконец в процедуру Timer1_Timer, Visual Basic согласно новому значению x смещает imgЛовец чуть вправо.

Ждем следующего импульса и так далее. Вот и вся механика ловца.

Теперь поговорим о глобальном и локальном. В проекте я старался максимально придерживаться принципа инкапсуляции, все что можно я делал Private. Поглядите повнимательнее в код ловца. Вы видите 4 процедуры и 1 функцию. Именно они и обеспечивают эту механику. Никакая процедура и функция снаружи модуля в этой механике не участвуют. Ловец самодостаточен. Снаружи осуществляется только запуск двух методов объекта - Начальная_установка и Действие. Именно поэтому они сделаны Public, иначе их снаружи и запустить было бы нельзя. Но вся механика этих методов, опять же, находится внутри ловца, так что никакого нарушения суверенитета нет. Остальные процедуры и функции сделаны Private, они снаружи и не видны и недоступны.

Всю мыслительную работу ловец выполняет сам. Было бы логично, если бы он сам и передвигал imgЛовец, то есть, если бы строки

imgЛовец.Left = Ловец.x

imgЛовец.Top = Ловец.y

находились бы не в модуле формы, а в модуле класса. Здесь это можно было сделать просто, но в том, что касается шаров, пришлось бы пойти на некоторое усложнение программы, и я на это не пошел ни там, ни там.

Теперь о переменных. Две переменные, dx и dy, объявлены Private, поэтому они не видны снаружи. И не надо, естественно. А вот переменные x и y объявлены Public, от этого они стали свойствами. Принцип инкапсуляции плачет. Зачем нужно было это делать? Для чего они нужны снаружи? Только для смещения imgЛовец. Если бы объект Ловец смещал свое изображение сам, то и не надо было бы делать x и y свойствами. Ну ладно. Сделал так сделал. А уж если так, то надо бы сделать их, по крайней мере, только для чтения. Я займусь этим в 20.8.

Вот и все о первой ступени проекта.

Дата добавления: 2014-12-23