Часть III. Программирование на Visual Basic - второй уровень

Проект - Гонки (игра)

Мы с вами разобрали уже два больших проекта: "Калькулятор" и "Будильник". Но "Калькулятор" можно не считать, на нем мы просто знакомились с Visual Basic. Выходит, "Будильник" - единственный большой проект, который написан более-менее правильно. И этого, конечно, мало. Вам нужен опыт создания проектов, в частности проектов с движением объектов по форме, да к тому же под управлением мыши и клавиатуры. Поэтому я решил разобрать с вами еще один проект (строк на 180). На этот раз это будет игра.

Постановка задачи

Вот внешний вид игры (о красотах я не заботился, красоты вы всегда сможете добавить по вкусу):

Процесс игры таков. Вы нажимаете на кнопку Начинаем сначала. На форме рисуется квадратное поле для гонки со случайно расположенными газонами. Нажатием на клавишу пробела вы даете газ и машина со старта набирает скорость. Ваша цель - любым путем побыстрее добраться до финиша. На белом асфальте вы можете газовать до любой скорости. Если же ненароком попадете на газон, то на газоне ваша скорость будет очень мала (я выбрал 15). Поэтому имеет смысл по газонам ездить пореже. Направление движения может быть только горизонтальное и вертикальное, наискосок машина не движется. Выбор направления (руль) - это клавиши со стрелками. Тормоз - клавиша B (английская). Тормозить надо по той причине, что на слишком большой скорости руль отказывает (это не потому, что проект плохой, а потому что я так придумал). В ограждение врезаться нельзя - катастрофа. Когда приедете на финиш, посмотрите на счетчик времени - это ваш результат. Снова нажимаете на кнопку Начинаем сначала. Теперь расположение газонов будет другим. Сажайте за клавиатуру приятеля и смотрите, не покажет ли он время лучшее, чем ваше. Можете посмотреть, кто из вас покажет лучшее время из 10 заездов. И тому подобное.

Не удивляйтесь, что скорость на спидометре не равна пути, деленному на время. Ведь это мгновенная (то есть настоящая скорость в данное мгновение), а не средняя скорость автомобиля (см. Физика, 9 класс).

Все эти правила я старался сделать как можно проще, чтобы не усложнять проект. Разобравшись в проекте, вы всегда сможете дописать процедуры, делающие процесс гонки более для вас привлекательным.

Для проекта я выбрал вариант игры с одним автомобилем. Я вам намекну, как модифицировать проект, чтобы получилась игра с двумя автомобилями. Однако помните, что для грамотного создания игры с несколькими автомобилями вам нужно будет подняться на новый уровень программирования - научиться создавать собственные классы объектов.

Делим проект на части

Начнем создавать проект. Прежде всего, как положено, разделим его по возможности на части. Мы уже делили проект на части, когда создавали будильник. Сейчас вам очень полезно перечитать тот материал. И проглядеть ту программу.

Сразу же бросается в глаза, что наша задача распадается на две последовательные почти независимые части:

1. Сначала рисование поля и всех его элементов, выкатывание машины на старт, обнуление скорости, времени и пути - в общем, все то, что должно быть сделано после нажатия на кнопку Начинаем сначала, но до начала движения. Этим будет заниматься одна группа процедур.

2. Затем управление машиной и событиями во время гонки. Этим будет заниматься другая группа процедур. Мы полностью задействуем идею использования таймера, так, как я ее изложил в 11.3. На каждом импульсе таймера автомобиль должен будет проделывать весь цикл своего функционирования.

Первая часть

Поскольку в первой части нет движения, то, в общем, все равно, что именно рисовать сначала, что потом, но и здесь следование житейской логике дает некоторую экономию кода и смысла:

1. Сначала нарисуем большой квадрат поля (ограждение), затем

2. Рисуем старт

3. Рисуем финиш

4. Рисуем газоны

5. Ставим машину на старт и обнуляем показания приборов

В общем, идеология первой части ясна. Пора разбираться в полном тексте программы, приведенном ниже. Здесь вам бы очень помогло, если бы программа уже находилась в вашем компьютере. Вам было бы легко и приятно в такт моим словам нажимать клавишу F8.

Начнем сверху. Разберитесь в объявленных переменных, не вникая пока в те, что относятся к движению.

Разобрались? Теперь идем дальше. Первая процедура, которая выполняется в проекте, это, конечно, Form_Load. В каждом проекте в ней удобно программировать все действия и вычисления, которые нужно выполнить один раз за все время работы проекта, в самом начале. В нашем случае это в основном задание и вычисление значений переменных величин - размеров элементов поля игры. Кое-что здесь нуждается в пояснении:

WindowState - это не переменная, а свойство формы. Вы помните, что свойства формы, в отличие от свойств других объектов, можно писать, не указывая хозяина (Form1.WindowState).

ScaleLeft и ScaleTop. Это тоже свойства формы. Мы их устанавливаем, если нам не нравится, что начало системы координат находится в левом верхнем углу формы.ScaleLeft занимается смещением начала координат по горизонтали, ScaleTop - по вертикали. Примеры:

Оператор	Смысл
ScaleLeft = 1000	Начало системы координат смещается налево на 1000 твипов
ScaleLeft = -500	Начало системы координат смещается направо на 500 твипов
ScaleTop = 800	Начало системы координат смещается вверх на 800 твипов
ScaleTop = -500	Начало системы координат смещается вниз на 500 твипов

В нашем проекте мы, конечно, могли бы обойтись и без этого, но многие операторы рисования у нас запишутся гораздо проще, если начало координат находится в левом верхнем углу поля игры, а не формы.

Все числа, которые встречаются в программе, я подобрал на опыте, исходя из размеров экрана и быстродействия своего компьютера. Вы можете эти числа изменить и посмотреть, что получится.

После выполнения процедуры Form_Load вы видите распахнутую на весь экран пустую форму с четырьмя текстовыми полями, тремя метками и кнопкой, ждущей нажатия. После щелчка по этой кнопке должна в полном объеме выполнится первая часть нашего проекта, так, как она описана выше. Заглянем в процедуру Кнопка_начинай_сначала_Click.

Здесь процедуры рисования ограждения, старта и финиша ясны без пояснений. Поясню процедуру Рисуем_газоны. Вы видите, что некоторые переменные я объявил внутри процедуры. Так поступают, когда знают, что значения этих переменных нигде, кроме как в этой процедуре, не нужны. Значения чисел и вид формул для X_газона и Y_газона я выбрал так, чтобы газоны не накладывались ни на ограждения, ни на старт с финишем.

Процедуру Ставим_машину_на_старт я поясню во второй части, так как она больше относится к ней.

Оператор Спидометр.SetFocus, появился вот почему. При запуске проекта фокус автоматически устанавливается на кнопку "Начинаем сначала". Кнопка в фокусе перехватывает нажатия на стрелки, в результате чего первое нажатие во время гонки на клавишу со стрелкой приводило не к выбору направления машиной, а к перескакиванию фокуса с кнопки на другой объект формы. Оператор Спидометр.SetFocus просто увел фокус с кнопки.

Вот, в общем, и все, что касается первой части. После ее выполнения мы увидим все, что нужно для старта, процедура Ставим_машину_на_старт поставит машину на старт, мотор будет заведен, вам останется только коснуться руля или педалей, чтобы началась часть вторая. Перейдем к ней.

Вторая часть

Если с первой частью все просто, то про вторую стоит поговорить подробнее. Фактически, нам нужно будет создавать автомобиль, как раньше мы создавали будильник. Не имея программистского опыта, мы попытаемся использовать житейский опыт касательно того, как автомобиль устроен. Причем применительно к задачам проекта. Так, цвет сиденья нам не очень важен в этом смысле. А важно нам управлять скоростью и направлением движения (этим в обычном автомобиле занимаются руль и педали газа и тормоза). А еще важно, чтобы автомобиль чувствовал, "куда он въехал" (газон, ограждение, финиш) и вел себя соответственно.

Итак, на каждом импульсе таймера автомобиль должен будет проделать весь цикл своего функционирования:

· Определить, где он находится (асфальт, газон, ограждение, финиш) и действовать соответственно.

· Изменить или не изменить скорость в соответствии с приказами клавиатуры.

· Изменить или не изменить в соответствии с приказами клавиатуры направление движения и сделать очередной шаг в нужном направлении.

· Изменить нужным образом показания приборов на пульте управления.

Но прежде, чем заниматься всем этим, давайте возьмем быка за рога и сразу посмотрим, как с клавиатуры примитивно управлять движением автомобиля.

Создайте отдельный пустой проект и поместите на форму объект Image. Дайте ему имя Image_авто. Чтобы он был виден в режиме работы, придайте значение его свойству BorderStyle. Он будет слушаться клавиш со стрелками при помощи такой программы:

Dim x As Integer 'Горизонтальная координата

Dim y As Integer 'Вертикальная координата

Private Sub Form_Load()

x = Image_авто.Left

y = Image_авто.Top

End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

Select Case KeyCode

Case vbKeyRight: x = x + 100

Case vbKeyLeft: x = x - 100

Case vbKeyDown: y = y + 100

Case vbKeyUp: y = y - 100

End Select

Image_авто.Left = x

Image_авто.Top = y

End Sub

Эта программа только иллюстрирует идею, но для проекта она не годится. Во-первых, потому, что для непрерывного движения объекта необходимо клавишу держать все время нажатой, что создает трудности при обработке нажатия в это время других клавиш. Во-вторых, сложные проекты с таймерами всегда должны помнить, куда они едут, а для этого нужна переменная величина. Есть и другие причины.

Создадим переменную, назовем ее Руль и сделаем перечислимой (см. объявления в тексте программы). Она выполнит предназначенную ей роль - помнить, куда мы едем. Создадим также перечислимую переменную Педаль (см. там же). Она будет хранить информацию о том, нажали ли мы педаль газа, тормоза или вообще на педаль не нажимали. Теперь разберемся с процедурой Form_KeyDown. Вы видите, что переменная Руль будет чувстврвать нажатие на стрелки только тогда, когда скорость движения автомобиля меньше пороговой. О том, что на педали пока не нажимали, сообщает компьютеру процедура Ставим_машину_на_старт. Именно поэтому после нажатия кнопки Начинаем сначала машина сама не срывается со старта, несмотря на работающий мотор. Оператор Клавиатура_сработала = True нужен для того, чтобы запустить счетчик времени

If Клавиатура_сработала Then Время = Время + 1

в процедуре Отображаем_информацию).

Итак, при нажатии нужных клавиш меняются значения нужных переменных. Но дела никакого не происходит. О деле чуть позже, а сейчас давайте подумаем, как сделать так, чтобы автомобиль глядел в ту же сторону, куда он едет. Есть всего 4 направления движения, значит и 4 ориентации автомобиля. Нужно всего лишь взять 4 картинки автомобиля с разной ориентацией и вовремя их менять. Откуда взять картинки? Нарисовать одну в графическом редакторе, а там ее легко поворачивать в нужном направлении и сохраняться. Сохранитесь в 4 файлах. Если вы не хотите рисовать, возьмите из папки с иконками Visual Basic, о которой я уже говорил, 4 иконки в виде стрелок, направленных в разные стороны. Вот вам и автомобиль.

Затем поместите на форму 4 объекта Image, дайте им имена Image_вверх, Image_вниз, Image_налево, Image_направо и придайте им соответствующие картинки. Чтобы эти объекты не мозолили глаза, сделайте их невидимыми. Вся механика будет заключаться в том, что когда вы нажимаете на клавиатуре стрелку вверх, должен выполняться оператор

Image_авто.Picture = Image_вверх.Picture

а когда вниз - то оператор

Image_авто.Picture = Image_вниз.Picture

И так далее.

Теперь можно разбираться в тексте процедур.

Мы с вами чуть выше определили четыре вещи, которые должен проделать автомобиль на каждом импульсе таймера. Посмотрите в процедуру Timer1_Timer и найдите там обращения к соответствующим процедурам. Из них нас сейчас интересует процедура Выбираем_куда_ехать_и_делаем_шаг. Именно она задает направление движения. Загляните в нее. Ее дело - чувствовать одно из 4 значений переменной Руль и запускать соответствующую из 4 процедур. Каждая из этих процедур делает две вещи: поворачивает машину в нужном направлении и меняет в этом направлении ее координату. Само же изображение автомобиля прыгнет на указанную координату чуть позже - во время выполнения процедуры Показываем_автомобиль.

Теперь посмотрим, как регулируется скорость. Прежде всего, при нажатии кнопки Начинаем сначала скорость устанавливается в ноль процедурой Ставим_машину_на_старт. В процессе гонки скорость регулируется процедурой Изменяем_скорость. Действие ее полностью определяется значением переменной Педаль. Если это газ, то на данном такте таймера скорость возрастет на 5. Если тормоз - упадет на 10 (потому что тормоз обычно действует сильнее газа). Как видите, значение переменной Педаль в конце процедуры принудительно приравнивается никакой педали. Это значит, что на следующем такте таймера скорость не изменится. Чтобы она изменилась, нам нужно еще раз нажать на клавишу газа или тормоза. Обычно поступают по-другому - просто удерживают клавишу нажатой, при этом событие KeyDown возникает несколько раз в секунду и скорость меняется достаточно быстро. Это соответствует механике реального автомобиля - чтобы набирать скорость, нужно непрерывно держать нажатой педаль газа, а чтобы тормозить - тормоза.

Процедура Отображаем_информацию заботится о том, чтобы на каждом такте в текстовых полях Спидометр, txtПуть и txtВремя были правильные цифры. В нашем проекте переменная Скорость только называется скоростью, а на самом деле это расстояние, на которое перемещается машина на одном такте таймера. Поэтому для вычисления суммарного пути, пройденного автомобилем, вполне уместен оператор Путь = Путь + Скорость. Переменная Время тоже является не временем в секундах, а количеством тактов таймера, прошедших со старта.

Теперь о процедуре Определяем_где_мы. Ее задача - задать реакцию автомобиля на три ситуации: попадание на газон, на финиш и на полосу ограждения. Метод, при помощи которого автомобиль определяет, где он, самый простой - Point. Его мы разобрали в 9.7. Поскольку газон я рисовал сиреневым (vbMagenta), финиш - синим, а ограждение - красным, то метод Point выдает на них разные результаты. Оператор Select эти результаты анализирует и задает реакцию автомобиля. Как видите, на сиреневое компьютер реагирует только установкой скорости = 15, на два других цвета он выдает сообщение в текстовое поле Сообщение, выключает мотор и устанавливает переменную Приехали, чтобы компьютер ее тут же проанализировал (см. процедуру таймера) и вышел из процедуры таймера, так как, когда приехали, делать, естественно, больше нечего.

В процедуре Ставим_машину_на_старт вы вполне сможете разобраться по комментариям самостоятельно.

Ну вот, кажется, и все пояснения.

Текст программы

Dim x As Integer 'Горизонтальная координата автомобиля

Dim y As Integer 'Вертикальная координата автомобиля

Dim X_старта As Integer 'Координаты старта и финиша

Dim Y_старта As Integer

Dim X_финиша As Integer

Dim Y_финиша As Integer

Dim Размер_старта As Integer 'Старт - квадрат, это сторона квадрата

Dim Размер_финиша As Integer 'Финиш - квадрат, это сторона квадрата

Dim Число_газонов As Integer 'Каждый газон - это случайный прямоугольник в случайном месте

Dim Максимальный_размер_газона As Integer

Dim Размер_поля As Integer 'Поле - квадрат, это сторона квадрата

Dim Отступ_поля_от_края_формы As Integer 'Имеется в виду отступ слева и сверху

Dim Путь As Long 'Путь автомобиля с момента старта (в твипах)

Dim Время As Integer 'Время измеряется количеством импульсов таймера с момента щелчка по кнопке начала

Dim Скорость As Integer 'Скорость - это не скорость, а расстояние. Она численно равна шагу автомобиля на каждом такте таймера

Dim Пороговая_скорость As Integer 'Скорость, выше которой не работает руль

Dim Цвет_под_автомобилем As Long 'Нужен чтобы знать, где находится автомобиль - на газоне, на финише, врезался в ограждение

Private Enum типРуль

вверх

влево

вниз

вправо

End Enum

Dim Руль As типРуль

Private Enum типПедаль

тормоз

газ

ни_та_ни_эта

End Enum

Dim Педаль As типПедаль

Dim Приехали As Boolean 'Приехали = True, когда приехали на финиш или врезались в ограждение

Dim Клавиатура_сработала As Boolean 'Чтобы секундомер судьи запускался автоматически, когда мы стартуем, не раньше

Private Sub Form_Load()

Timer1.Enabled = False 'Нечего мотору зря работать до начала гонки

Randomize 'Нам придется рисовать случайные газоны

WindowState = 2 'Окно игры распахнуто на весь экран

BackColor = vbWhite 'Асфальт белый

'Задаем и вычисляем размеры элементов поля (все числа подбирайте еа опыте):

Отступ_поля_от_края_формы = 500

ScaleLeft = -Отступ_поля_от_края_формы 'Смещаем для удобства начало системы координат в левый верхний угол поля

ScaleTop = -Отступ_поля_от_края_формы

Размер_поля = Screen.Height - 2 * Отступ_поля_от_края_формы 'Отступ от края экрана должен быть и снизу

Размер_старта = 600

Размер_финиша = 600

X_старта = Размер_поля - Размер_старта 'Чтобы старт находился у правой кромки поля

X_финиша = 0 'Чтобы финиш находился у левой кромки поля

Y_старта = Размер_поля / 2 'Чтобы старт по высоте находился посредине поля

Y_финиша = Размер_поля / 2 'Чтобы финиш по высоте находился посредине поля

Число_газонов = 30

Максимальный_размер_газона = Размер_поля / 6

Пороговая_скорость = 200

End Sub

Private Sub Кнопка_начинай_сначала_Click()

Клавиатура_сработала = False 'Мы еще не стартовали

Timer1.Enabled = False 'Нечего мотору зря работать до начала гонки

'Рисуем поле игры со всеми элементами:

Cls 'Перед тем, как заново рисовать, надо все стереть

Рисуем_границы_поля

Рисуем_старт

Рисуем_финиш

Рисуем_газоны

'Необходимые начальные установки:

Ставим_машину_на_старт

Приехали = False

Timer1.Enabled = True 'Заводим мотор, скоро начало гонки

Спидометр.SetFocus 'Это чтобы фокус ушел с кнопки, а то первое нажатие на стрелку действует не так, как нам надо

End Sub

Private Sub Рисуем_границы_поля()

DrawWidth = 10

Line (0, 0)-(Размер_поля, Размер_поля), vbRed, B

DrawWidth = 1 'Возвращаем нормальную толщину карандаша

End Sub

Private Sub Рисуем_старт()

Line (X_старта, Y_старта)-(X_старта + Размер_старта, Y_старта + Размер_старта), vbGreen, BF

End Sub

Private Sub Рисуем_финиш()

Line (X_финиша, Y_финиша)-(X_финиша + Размер_финиша, Y_финиша + Размер_финиша), vbBlue, BF

End Sub

Private Sub Рисуем_газоны() 'Каждый газон - это прямоугольник случайного размера в случайном месте

Dim i As Integer

Dim X_газона As Integer 'Горизонтальная координата верхнего левого угла газона

Dim Y_газона As Integer 'Вертикальная координата верхнего левого угла газона

For i = 1 To Число_газонов 'Числа в формулах подобраны на опыте:

X_газона = 2 * Размер_финиша + Размер_поля * Rnd * 2 / 3

Y_газона = Размер_финиша + (Размер_поля - Размер_финиша - Максимальный_размер_газона) * Rnd

Line (X_газона, Y_газона)-(X_газона + Максимальный_размер_газона * Rnd, Y_газона + Максимальный_размер_газона * Rnd), vbMagenta, BF

Next

End Sub

Private Sub Ставим_машину_на_старт()

x = X_старта: y = Y_старта 'Координаты машины приравниваются координатам точки старта

Скорость = 0: Путь = 0: Время = 0

Руль = влево 'Это чтобы машина знала, куда ехать, когда стартуем нажатием на газ

Едем_влево 'Отсюда нам нужна только ориентация машины налево, а шага не будет, так как скорость=0

Педаль = ни_та_ни_эта 'Газовать пока нельзя, а тормозить бессмысленно

Image_авто.Visible = True 'До первого старта я сделал машину невидимой, теперь пришла пора ей появиться

Показываем_автомобиль

End Sub

Private Sub Timer1_Timer()

Определяем_где_мы

If Приехали Then Exit Sub

Изменяем_скорость

Выбираем_куда_ехать_и_делаем_шаг

Показываем_автомобиль

Отображаем_информацию

End Sub

Private Sub Определяем_где_мы()

Цвет_под_автомобилем = Point(x, y)

Select Case Цвет_под_автомобилем

Case vbMagenta: Скорость = 15 'На газоне скорость мала

Case vbBlue: Сообщение.Text = "Финиш!": Timer1.Enabled = False: Приехали = True

Case vbRed: Сообщение.Text = "Врезались в ограждение!": Timer1.Enabled = False: Приехали = True

End Select

End Sub

Private Sub Изменяем_скорость()

Select Case Педаль

Case газ

Скорость = Скорость + 5

Case тормоз

If Скорость > 0 Then Скорость = Скорость - 10 'потому, что тормоз быстрее газа

If Скорость < 0 Then Скорость = 0 'В результате быстрого торможения скорость может стать отрицательной, что и предотвращается

End Select

Педаль = ни_та_ни_эта 'Это чтобы во время набора скорости и торможения приходилось без перерыва жать на педаль

End Sub

Private Sub Выбираем_куда_ехать_и_делаем_шаг()

Select Case Руль

Case вверх: Едем_вверх

Case вниз: Едем_вниз

Case влево: Едем_влево

Case вправо: Едем_вправо

End Select

End Sub

Private Sub Едем_вверх()

Image_авто.Picture = Image_вверх.Picture

y = y - Скорость

End Sub

Private Sub Едем_вниз()

Image_авто.Picture = Image_вниз.Picture

y = y + Скорость

End Sub

Private Sub Едем_влево()

Image_авто.Picture = Image_налево.Picture

x = x - Скорость

End Sub

Private Sub Едем_вправо()

Image_авто.Picture = Image_направо.Picture

x = x + Скорость

End Sub

Private Sub Показываем_автомобиль()

Image_авто.Left = x

Image_авто.Top = y

End Sub

Private Sub Отображаем_информацию()

Спидометр.Text = Скорость

Путь = Путь + Скорость 'Нужно помнить, что именем Скорость назван шаг автомобиля

txtПуть.Text = Путь

If Клавиатура_сработала Then Время = Время + 1 'Счетчик времени запускается только тогда, когда мы стартуем

txtВремя.Text = Время

End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

Клавиатура_сработала = True

Select Case KeyCode

Case vbKeyUp: If Скорость < Пороговая_скорость Then Руль = вверх 'Поворот на большой скорости запрещен

Case vbKeyLeft: If Скорость < Пороговая_скорость Then Руль = влево

Case vbKeyDown: If Скорость < Пороговая_скорость Then Руль = вниз

Case vbKeyRight: If Скорость < Пороговая_скорость Then Руль = вправо

Case vbKeySpace: Педаль = газ

Case vbKeyB: Педаль = тормоз

End Select

KeyCode = 0 'Это чтобы объекты на форме не реагировали на клавиатуру

End Sub

Недоработки проекта

Замеченные мной недоработки вызваны в основном нежеланием увеличивать размер кода и заключаются в следующем:

· Координатами (х,у) машины считается ее левый верхний угол, а не центр. Причина этого - слишком простые операторы в процедуре Показываем_автомобиль. Это приводит к некоторой ассиметрии поведения машины при переезде с цвета на цвет. Немного повозившись, вы сможете исправить положение.

· При большой скорости машина делает огромные шаги от одного такта таймера к другому. А ведь цвет под собой она ощущает не непрерывно, а только на тактах таймера. Значит она может перепрыгнуть через тоненький газон, не заметив его. То же относится к финишу и особенно к ограждению. Сделайте их потолще, чем у меня на картинке, или ограничьте скорость.

· Сам бог велел вам добавить в проект управление машиной с помощью мыши. Например, щелчок мышью в стороне от машины вызывает поворот машины в эту сторону, удерживание нажатой левой клавиши мыши - газ, правой - тормоз. Для этого вам нужно будет написать процедуру MouseDown, придавая в ней нужные значения переменным Руль и Педаль аналогично тому, как это делает процедура KeyDown. Вам придется поразмыслить, как правильно сравнить координаты машины и мыши, чтобы добиться нужного результата.

Гонки двух автомобилей

Если вы хотите играть вместе с другом, вам нужны гонки двух машин. Несмотря на то, что ничего нового вам придумывать не придется, размер программы вырастет раза в полтора. Для второй машины нужен будет второй таймер. Вам придется иметь по два экземпляра переменных, описывающих поведение каждой машины. Например, вместо переменной Скорость вам придется иметь две переменные - Скорость1 и Скорость2. Вам придется иметь по два экземпляра процедур, задающих поведение каждой машины. Процедуру KeyDown вам придется дополнить новыми клавишами для управления второй машиной. При этом нужно будет внести серьезные изменения в педали, так как удерживать клавиши нажатыми теперь будет нельзя без усложнения программы. Вы могли бы сократить рост программы, используя процедуры с параметрами, но пока у вас для этого нет достаточных знаний. А если у вас гонки 10 автомобилей? Проблемы нарастают.

Visual Basic конечно же предлагает универсальное решение этой проблемы. Он, как и все серьезные и мощные языки программирования, является объектно-ориентированным языком. В частности, имеется в виду, что он позволяет программисту создавать собственные классы объектов. Вот у вас имеется класс объектов "кнопка" - CommandButton и вы пользуетесь в проекте отдельными экземплярами этого класса - объектами. Поведение кнопок запрограммировано глубоко внутри Visual Basic и вы видите только результаты этого программирования. Например, когда выполняется оператор

Command1.Visible = True

вы видите, что кнопка легко возникает на форме. Однако, чтобы она возникла, нужно чтобы компьютер ее нарисовал из прямоугольников и других элементов и написал что-то на ней, а для этого нужна программа.

Научившись создавать собственные классы, вы сможете создать класс "автомобиль" и пользоваться каким угодно числом экземпляров этого класса. Программу поведения автомобиля вы пишете сами, причем один раз и только для одного автомобиля. Остальные автомобили будут автоматически пользоваться ей же. Как все это делается, описывается в Глава 20.

12.4. Задание на игру “Торпедная атака

Задание 114: “ Торпедная атака ”. Начинается все красивой заставкой с названием игры. Компьютер спрашивает ваше имя, чтобы во время игры оно горело красивыми яркими буквами в углу экрана. В меню вы можете посмотреть правила игры, сведения об авторе, выбрать игру со звуком или без. Но вот игра началась. На экране морской пейзаж (нарисованный вами или взятый готовым). Вдали экрана по горизонтали плывет вражеский корабль. У нижнего края экрана притаился ваш торпедный аппарат. В подходящий момент времени вы нажимаете клавишу - и торпеда плывет вдаль, уменьшаясь по мере удаления. Если вы попали, то экран озаряется вспышкой от взрыва, на мгновение виден и сам взрыв, раздается коротенькая радостная мелодия, на экране - коротенький поздравительный текст, счетчик подбитых кораблей на экране увеличивается на 1. Если не попали, то зрительные и звуковые эффекты - совсем другие. В любом случае уменьшается на 1 счетчик оставшихся торпед. Затем плывет следующий корабль. И так далее. Когда торпеды у вас кончатся (скажем, их было 10), игра заканчивается. Программа анализирует ваши успехи и в зависимости от них выдает на экран текст, скажем “Мазила!”, если вы не попали ни разу из 10, или “Профи!”, если вы попали 8 раз. Затем спрашивает, будете ли вы играть еще.

Помощь: Как компьютер определит, попал или не попал? Нужно в тот момент, когда торпеда доплывет до линии движения корабля, сравнить горизонтальные координаты корабля и торпеды, и если они достаточно близки, считать, что попал.

Улучшение. Если у всех кораблей будет одинаковая скорость, то попадать будет слишком просто, а значит и играть неинтересно. Сделайте скорость кораблей случайной. Конечно, не совсем уж (скажем, в условных единицах скорости диапазон от 0 до 10 – это слишком), а в пределах разумного (скажем, от 4 до 8 – это нормально). Причем не нужно менять скорость одного и того же корабля в процессе движения. Пусть она остается постоянной, а то все будет зависеть не от вашего мастерства, а от везения. Различаются скорости только разных кораблей.

Пусть игрок сможет выбирать из нескольких уровней трудности. Трудность удобнее всего увеличивать, уменьшая размеры корабля, то есть требуемую величину близости координат корабля и торпеды при определении попадания.

_______________ _ _________________

Мы с вами закончили первый из двух циклов знакомства с Visual Basic. Если вам удалась «Торпедная атака» и она работает не хуже, чем указано в задании, то у вас должна появиться уверенность, что теперь, умело разбивая программы проекта на небольшие процедуры, вы можете создавать проекты любой сложности, а значит цель этого цикла достигнута. Я вас поздравляю - вам присваивается звание “ Программист-любитель III ранга ”!

Если вам кажется, что вы уже все можете, то вы правы и неправы. Правы потому, что вы можете написать сколь угодно большую программу, разбив ее на разумное число процедур. Неправы потому, что ваша способность манипулировать данными разных типов еще очень ограничена. А без нее вам не поддадутся «умные» задачи. Например, не познакомившись с так называемыми массивами, вы не сможете запрограммировать игру в крестики-нолики или морской бой. Не освоив работу со строками, вы не сможете решить задачу о мало-мальски серьезной шифровке и расшифровке секретных сообщений. Не умея работать с файлами, вы не сможете сохраняться в созданных вами играх. Вам нужно освоить начала объектного программирования, познакомиться с базами данных, с работой в Интернете и с другими вещами.

Если в предыдущей части главной целью было научить вас программировать сложные проекты для работы с простыми данными, то теперь главная цель - программировать простые проекты для работы со сложными данными. В этой части я предполагаю, что предыдущую часть вы прочитали и задания выполнили.

Если в предыдущей части я вводил новые элементы Visual Basic бессистемно, только тогда, когда они нужны были в процессе изучения программирования, то сейчас я буду вводить их систематически и рассматривать их более полно, независимо от того, нужны они вам сейчас или пригодятся позже.

Глава 13. Массивы

Массивы- одно из главных средств хранения в памяти компьютера больших объемов информации.

Для того, чтобы понять массивы, нужно обладать некоторой культурой математического мышления. Если этот материал покажется вам трудным, не поддавайтесь искушению пропустить его. Настоящего программирования без массивов не бывает, да и большая часть дальнейшего материала без массивов не будет понятна.

В основе массивов лежит понятие индекса.

Дата добавления: 2014-12-23