Структура программы управления приводом

Рис. 6.6.Структура таймерного управления приводом

Программная реализация установки нового таймерного вектора прерывания и настройки таймера на заданную частоту представлена в макрокоманде TaimIni freq, vector. Параметры freq, vector - формальные параметры для задания частоты таймера и вектора прерывания, которые при вызове макрокоманды замещаются на фактические параметры.

Рассмотрим макроопределение команды:

TaimIni MACRO freq,vector;инициализация канала «0»;таймера с настройкой частоты и вектора прерывания.

mov al,0;очиска масок прерываний в контроллере

out 21h, al;прерываний, используя порт 21h

cli;запретить прерывания процессору

push ds;сохранить значение регистра ds

push es;сохранить значение регистра es

mov ah,35h;сохранить старый вектор прерывания

mov al,08h;№8 в отведенных нами ячейках памяти

int 21h;для последующего его восстановления

mov [oldip8],bx;адрес смещения в ячейку [oldip8]

mov [oldcs8],es;адрес сегмента в ячейку [oldcs8]

mov dx,offset vector;адрес обработчика - смещение

mov ax,seg vector;адрес обработчика -сегмент

mov ds,ax;в регистр ds

mov ah,25h;функция 25h прерывания 21h

mov al,08h;для прерывания с N8 (таймера)

int 21h;программное прерывание DOS

mov al,00110110b;код для настройки регистра

out 43h,a;с адресом 43h

mov ax, freq;задание частоты - делитель

out 40h,al;загрузить в порт 40h

mov al,ah;т.е. делитель -в регистр данных

out 40h,al;таймера

pop es;восстановить

pop ds;использованные регистры

sti;разрешить внешние прерывания

ENDM;конец макроопределения

;================

Выход из таймерных прерываний выполняется макрокомандой ExitInt, которая восстанавливает системный вектор прерывания по таймеру и его настройку на системную частоту 18,2Гц.

ExitInt MACRO;Выход из программы прерываний

cli;запретить прерывания (FI=0) на время

mov al,00110110b;программирования нулевого канала

out 43h,al;таймера на частоту 18,2 Гц.

sub ax,ax;в регистр данных таймера заносится 0

out 40h,al;и выполняется деление

mov al,ah;193180:65536=18,2Гц

out 40h,al;

push ds;сохpанить регистры

push es;

mov dx,[oldip8];прежнее смещение вектора - в dx

mov ax,[oldcs8];прежний сегмент вектора -

mov ds,ax;в регистр ds

mov ah,25h;функция 25 прерывания 21h DOS

mov al,08h;загрузит старый вектор по адресу

int 21h;в таблицу прерываний для №8

pop es;восстановить использованные

pop ds;регистры

mov al,0;очистка масок прерываний

out 21h,al;в регистре 21h контроллера прерываний

sti;разрешение прерываний

ENDM

Дата добавления: 2014-01-11